CMD script to export the Delphi HKCU registry branches

Batch, Delphi 1 Minute

Just in case anybody else has a use for this: Here is a CMD script that exports the HKCU registry branches for all Delphi version from XE2 to 13:

@echo off
setlocal

set "OUTDIR=%~dp0registry_exports"
if not exist "%OUTDIR%" mkdir "%OUTDIR%"

call :ExportBDS  9.0 XE2
call :ExportBDS 10.0 XE3
call :ExportBDS 11.0 XE4
call :ExportBDS 12.0 XE5
call :ExportBDS 14.0 XE6
call :ExportBDS 15.0 XE7
call :ExportBDS 16.0 XE8
call :ExportBDS 17.0 "10_Seattle"
call :ExportBDS 18.0 "10.1_Berlin"
call :ExportBDS 19.0 "10.2_Tokyo"
call :ExportBDS 20.0 "10.3_Rio"
call :ExportBDS 21.0 "10.4_Sydney"
call :ExportBDS 22.0 "11_Alexandria"
call :ExportBDS 23.0 "12_Athens"
call :ExportBDS 37.0 "13"

echo.
echo Done. Files written to %OUTDIR%
pause
goto :eof

:ExportBDS
set "BDS=%~1"
set "NAME=%~2"
set "KEY=HKCU\Software\Embarcadero\BDS\%BDS%"
set "FILE=%OUTDIR%\Delphi_%NAME%_BDS_%BDS%.reg"

reg query "%KEY%" >nul 2>&1
if errorlevel 1 (
    echo SKIP: Delphi %NAME% ^(BDS %BDS%^) - not found
) else (
    echo Export: Delphi %NAME% ^(BDS %BDS%^)
    reg export "%KEY%" "%FILE%" /y >nul
)
goto :eof
Published